Market Meanness Index [CC]

// Copyright (c) 2019-present, Franklin Moormann (cheatcountry)
// Market Meanness Index [CC] script may be freely distributed under the MIT license.
// ------------------------------------------------------------------------------------------------
// Original author:  cheatcountry
// Original title:   Market Meanness Index [CC]
// Licence:          MIT (the header above is the original notice, kept verbatim)
// Pine version:     5
// Fetched:          2026-10-12
// Ported to FloScript by FloSignals; modifications under MPL-2.0.
// Converter:        @flosignals/floscript 0.1.0, strict mode, score 100/100
// ------------------------------------------------------------------------------------------------
//@floscript=1
//@version=5
indicator('Market Meanness Index [CC]', overlay=false)

float inp = input.source(title="Source", defval=hlcc4)
string res = input.timeframe(title="Resolution", defval="")
bool rep = input.bool(title="Allow Repainting?", defval=false)
bool bar = input.bool(title="Allow Bar Color Change?", defval=false)
float src = inp[rep ? 0 : barstate.isrealtime ? 1 : 0][rep ? 0 : barstate.isrealtime ? 0 : 1]
int length = input.int(title="Length", defval=100, minval=2)

median = ta.median(src, length)
int nh = 0
nl = 0
for int i = 1 to length - 1
    currVal = nz(src[i])
    prevVal = nz(src[i - 1])

    if currVal > median and currVal > prevVal
        nl += 1
    else if currVal < median and currVal < prevVal
        nh += 1
mmi = 100 * (nl + nh) / (length - 1)

filt = 0.0
coef = 0.0
for i = 1 to length by 1
    cosine = 1 - math.cos(2 * math.pi * i / (length + 1))
    filt += cosine * nz(mmi[i - 1])
    coef += cosine
filt := coef != 0 ? filt / coef : 0

float slo = nz(filt[1]) - filt
int sig = slo > 0 ? (slo > nz(slo[1]) ? 2 : 1) : slo < 0 ? (slo < nz(slo[1]) ? -2 : -1) : 0
alertcondition(ta.crossover(sig, 1), 'Strong Buy Signal', 'Strong Bullish Change Detected')
alertcondition(ta.crossunder(sig, -1), 'Strong Sell Signal', 'Strong Bearish Change Detected')
alertcondition(ta.crossover(sig, 0), 'Buy Signal', 'Bullish Change Detected')
alertcondition(ta.crossunder(sig, 0), 'Sell Signal', 'Bearish Change Detected')
alertcondition(ta.crossover(sig, 0) or ta.crossover(sig, 1), "All Buy Signals", "Any Bullish Change Detected")
alertcondition(ta.crossunder(sig, 0) or ta.crossunder(sig, -1), "All Sell Signals", "Any Bearish Change Detected")
color mmiColor = sig > 1 ? color.green : sig > 0 ? color.lime : sig < -1 ? color.maroon : sig < 0 ? color.red : chart.fg_color
barcolor(bar ? mmiColor : na)
plot(filt, title='MMISmooth', color=mmiColor, linewidth=2)

This file is under the MIT License; it is a port of the original by cheatcountry, with the original licence header kept and the changes made for FloScript noted in the file.

• v22026-10-14

  Library refresh 2026-10-14

• v12026-10-12

  Library refresh 2026-10-12