Untitled

// This Pine Script™ code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © PineCodersTASC

//  TASC Issue: December 2024
//     Article: Revisualizing The ADX Oscillator
//  Article By: Neil Jon Harrington
//    Language: Pine-compatible v5
// Provided By: PineCoders, for tradingview.com
// ------------------------------------------------------------------------------------------------
// Original author:  PineCodersTASC
// Original title:   TASC 2024.12 Dynamic ADX Histogram
// Licence:          MPL-2.0 (the header above is the original notice, kept verbatim)
// Pine version:     5
// Fetched:          2026-10-12
// Ported to FloScript by FloSignals; modifications under MPL-2.0.
// Converter:        @flosignals/floscript 0.1.0, strict mode, score 100/100
// ------------------------------------------------------------------------------------------------
//@floscript=1
//@version=5

title = 'TASC 2024.12 Dynamic ADX Histogram'
stitle = 'DADX'
indicator(title, stitle)

int ADX_Length = input.int(10, "ADX Length", 1)
float ADX_THLo = input.float(15, "Low Threshold", 0)
float ADX_THHi = input.float(40, "High Threshold", 0)
int ADX_Smooth = input.int(1, "DMI Smoothing Length", 1)

string gu = 'Colors, Up:'
string gn = 'Neutral:'
string gd = 'Down:'
color col_OBUp = input.color(#00ffff, gu, inline=gu)
color col_OBWUp = input.color(#008b8b, '', inline=gu)
color col_Up = input.color(#09ff00, '', inline=gu)
color col_WUp = input.color(#048000, '', inline=gu)
color col_NUp = input.color(#383838, gn, inline=gn)
color col_Ndn = input.color(#000000, '', inline=gn)
color col_Wdn = input.color(#680000, gd, inline=gd)
color col_dn = input.color(#ff0000, '', inline=gd)
color col_OSWdn = input.color(#5c001f, '', inline=gd)
color col_OSdn = input.color(#ff00aa, '', inline=gd)

[DIP, DIN, DIA] = ta.dmi(ADX_Length, ADX_Length)
float NADX = -DIA
float SP = ta.sma(DIP, ADX_Smooth)
float SM = ta.sma(DIN, ADX_Smooth)
float NET = SP - SM

bool isDIAup = DIA > DIA[1]
bool isDIAdn = DIA < DIA[1]

color col = color(na)
if isDIAup
    col := col_NUp
if isDIAdn
    col := col_Ndn

float osc = na
switch
    NET >= 0 =>
        if DIA >= ADX_THHi
            if isDIAup
                col := col_OBUp
            if isDIAdn
                col := col_OBWUp
        if DIA >= ADX_THLo and DIA <= ADX_THHi
            if isDIAup
                col := col_Up
            if isDIAdn
                col := col_WUp
        osc := DIA
    NET < 0 =>
        if DIA >= ADX_THHi
            if isDIAup
                col := col_OSdn
            if isDIAdn
                col := col_OSWdn
        if DIA >= ADX_THLo and DIA <= ADX_THHi
            if isDIAup
                col := col_dn
            if isDIAdn
                col := col_Wdn
        osc := NADX

plot(osc, "ADXO", col, 1, plot.style_columns)

hline(ADX_THHi, 'High Threshold')
hline(ADX_THLo, 'Low Threshold')
hline(0, 'Zero')
hline(-ADX_THLo, '-Low Threshold')
hline(-ADX_THHi, '-High Threshold')

This file is under the Mozilla Public License 2.0; it is a port of the original by PineCodersTASC, with the original licence header kept and the changes made for FloScript noted in the file.

• v22026-10-14

  Library refresh 2026-10-14

• v12026-10-12

  Library refresh 2026-10-12